package{
	
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import fl.controls.*;
	
	public class WidgetFlip extends Sprite{
		
		private var fLen:Number=400;//CHANGE the focal length to tweak the amount of distortion
									//larger number == less distortion, smaller number == more distortion
		
		private var onTop = 1;
		
		private var picWidth:Number = 295; //CHANGE the width to the desired width of the object
		private var picHeight:Number = 195; //CHANGE the height likewise
		private var positionX:int = 18; //CHANGE the X position to create the desired padding
		private var positionY:int = 58; //CHANGE the Y position likewise
		
		private var isMoving:Boolean=false;
		
		private var spCard:Sprite=new Sprite();
		private var frontSide:Sprite=new Sprite();
		private var backSide:Sprite=new Sprite();
		
		private var firstSlices:Array=[]; 
		private var secondSlices:Array=[];
		
		private var sliceWidth:Number=1;
		private var numSlices:Number;
		
		private var bdFirst:BitmapData;
		private var bdSecond:BitmapData;
		
		private var curTheta:Number=0;
		private var dir:Number = 1;
		
		private var childContentFront:Sprite = new Sprite();
		private var childContentBack:Sprite = new Sprite();

		public function WidgetFlip(){
			
			bdFirst = new BitmapData(picWidth,picHeight);
			bdSecond = new BitmapData(picWidth,picHeight);
			
			numSlices = picWidth/sliceWidth;
			
			childContentFront = getFront();
			childContentBack = getBack();
			
			addChild(spCard);
			spCard.addChild(backSide);
			spCard.addChild(frontSide);
			frontSide.addChild(childContentFront);
			backSide.addChild(childContentBack);
			
			spCard.x=positionX;
			spCard.y=positionY;
			
			this.addEventListener(Event.ENTER_FRAME,onEnter);
		}
		
		function cutSlices():void {
			var i:int;
			
			for(i=0;i<numSlices-1;i++){
				
				firstSlices[i]=new Bitmap(new BitmapData(sliceWidth+1,picHeight));
				firstSlices[i].bitmapData.copyPixels(bdFirst,new Rectangle(i*sliceWidth,0,sliceWidth+1,picHeight),new Point(0,0));
				
				secondSlices[i]=new Bitmap(new BitmapData(sliceWidth+1,picHeight));
				secondSlices[i].bitmapData.copyPixels(bdSecond,new Rectangle(i*sliceWidth,0,sliceWidth+1,picHeight),new Point(0,0));
				
				backSide.addChild(firstSlices[i]);				
				frontSide.addChild(secondSlices[i]);

			}
			
			firstSlices[numSlices-1]=new Bitmap(new BitmapData(sliceWidth,picHeight));
			firstSlices[numSlices-1].bitmapData.copyPixels(bdFirst,new Rectangle((numSlices-1)*sliceWidth,0,sliceWidth,picHeight),new Point(0,0));
				
			secondSlices[numSlices-1]=new Bitmap(new BitmapData(sliceWidth,picHeight));
			secondSlices[numSlices-1].bitmapData.copyPixels(bdSecond,new Rectangle((numSlices-1)*sliceWidth,0,sliceWidth,picHeight),new Point(0,0));
				
			backSide.addChild(firstSlices[numSlices-1]);
			frontSide.addChild(secondSlices[numSlices-1]);
		}
		
		function renderView(t:Number):void {
			var j:int;
		
			var curv0:Array=[];
			var curv1:Array=[];
			var curv2:Array=[];
			var curv3:Array=[];
			
			var curNormal:Number;
			
			var factor1:Number;
			var factor2:Number;
			
			var curTransMatrix:Matrix;
			
			t=t*Math.PI/180;
			
			curNormal=Math.cos(t);
			
			if(curNormal>=0){
				for(j=0;j<numSlices;j++){
					firstSlices[j].visible=true;
					secondSlices[j].visible=false;
				}
			} else {
				for(j=0;j<numSlices;j++){
					firstSlices[j].visible=false;
					secondSlices[j].visible=true;
				}
			}
			
			for(j=0;j<numSlices;j++){
				factor1=fLen/(fLen-Math.sin(t)*(-picWidth/2+j*sliceWidth));
				factor2=fLen/(fLen-Math.sin(t)*(-picWidth/2+(j+1)*sliceWidth));
					
				curv0=[factor1*(-picWidth/2+j*sliceWidth)*Math.cos(t)+picWidth/2,-factor1*picHeight/2+picHeight/2];
				curv1=[factor2*(-picWidth/2+(j+1)*sliceWidth)*Math.cos(t)+picWidth/2,-factor2*picHeight/2+picHeight/2];
				curv2=[factor2*(-picWidth/2+(j+1)*sliceWidth)*Math.cos(t)+picWidth/2,factor2*picHeight/2+picHeight/2];
				curv3=[factor1*(-picWidth/2+j*sliceWidth)*Math.cos(t)+picWidth/2,factor1*picHeight/2+picHeight/2];
				
				curTransMatrix=calcMatrixForSides(curv0,curv1,curv2,curv3);
				
				firstSlices[j].transform.matrix=curTransMatrix;
			}
			
			for(j=0;j<numSlices;j++){
				factor1=fLen/(fLen-Math.sin(t)*(picWidth/2-j*sliceWidth));
				factor2=fLen/(fLen-Math.sin(t)*(picWidth/2-(j+1)*sliceWidth));
				
				curv0=[factor1*(picWidth/2-j*sliceWidth)*Math.cos(t)+picWidth/2,-factor1*picHeight/2+picHeight/2];
				curv1=[factor2*(picWidth/2-(j+1)*sliceWidth)*Math.cos(t)+picWidth/2,-factor2*picHeight/2+picHeight/2];
				curv2=[factor2*(picWidth/2-(j+1)*sliceWidth)*Math.cos(t)+picWidth/2,factor2*picHeight/2+picHeight/2];
				curv3=[factor1*(picWidth/2-j*sliceWidth)*Math.cos(t)+picWidth/2,factor1*picHeight/2+picHeight/2];
				
				curTransMatrix=calcMatrixForSides(curv0,curv1,curv2,curv3);
				
				secondSlices[j].transform.matrix=curTransMatrix;
			}
		}
		
		function calcMatrixForSides(v0:Array,v1:Array,v2:Array,v3:Array):Matrix {
			var curMatrix:Matrix;
			var transMatrix:Matrix;
			
			var v:Array=findVecMinusVec(v1,v0);
			var w:Array=findVecMinusVec(v3,v0);
			
			curMatrix=new Matrix(v[0]/sliceWidth,v[1]/sliceWidth,w[0]/picHeight,w[1]/picHeight);
			transMatrix=new Matrix(1,0,0,1,v0[0],v0[1]);
			curMatrix.concat(transMatrix);
			
			return curMatrix;
		}
		
		function findVecMinusVec(v:Array,w:Array):Array {
			return [v[0]-w[0],v[1]-w[1],v[2]-w[2]];
		}
		
		function sideClicked(e:MouseEvent):void {		
			bdFirst.draw(childContentFront);
			bdSecond.draw(childContentBack);
			
			backSide.removeChild(childContentBack);
			frontSide.removeChild(childContentFront);
			
			frontSide.visible = true;
			backSide.visible = true;
			
			cutSlices();
			
			if(isMoving==false){
				isMoving=true;
			}
		}
		
		function onEnter(e:Event): void {
			if(isMoving){
				if (dir == 1){
					curTheta+=18;
					curTheta=curTheta%360;
				}
				else if (dir == -1){
					curTheta-=18;
					curTheta=curTheta%360;
				}
						
				renderView(curTheta);
				
				if((curTheta%180)==0){
					isMoving=false;
					if (onTop == 0) onTop = 1;
					else onTop = 0;
					replaceBitmaps();//kill the bitmap, put the objects back
				}
			}
		}
		
		function replaceBitmaps():void{
			var i:int;
			
			for(i=0;i<numSlices;i++){
				backSide.removeChild(firstSlices[i]);
				frontSide.removeChild(secondSlices[i]);
			}
			
			frontSide.addChild(childContentFront);
			backSide.addChild(childContentBack);
			
			if (onTop == 0) {frontSide.visible = false; backSide.visible = true; dir = -1;}
			else {backSide.visible = false; frontSide.visible = true; dir = 1;}
		}
		
		//this method creates the front of the object
		private function getFront():Sprite{
			childContentFront = new Sprite();
			
			//CHANGE the lineStyle and fill for the front
			childContentFront.graphics.lineStyle(2, 0x555555, 1);
			childContentFront.graphics.beginFill(0xFFFFFF);
			childContentFront.graphics.drawRect(0, 0, picWidth, picHeight);
			childContentFront.graphics.endFill();
			
			//CHANGE this code to create the desired Flash objects for the front
			var pie:Pie = new Pie();
			childContentFront.addChild(pie);
			pie.x = 20;
			pie.y = 1;
			pie.height = picHeight;
			pie.width = picWidth - (picWidth/5);
			
			//CHANGE this code to change the icon that you click to flip the card
			var over:Over = new Over();
			childContentFront.addChild(over);
			over.x = 265;
			over.y = 175;
			over.addEventListener(MouseEvent.CLICK,sideClicked);
			
			return childContentFront;
		}
		
		//this method creates the back of the object
		private function getBack():Sprite{
			childContentBack = new Sprite();
			//CHANGE the lineStyle and fill for the back
			childContentBack.graphics.lineStyle(2, 0x555555, 1);
			childContentBack.graphics.beginFill(0xFFFFFF);
			childContentBack.graphics.drawRect(0, 0, picWidth, picHeight);
			childContentBack.graphics.endFill();

			//CHANGE this code to create the desired Flash objects for the back
			var accounts:ComboBox = new ComboBox();
			childContentBack.addChild(accounts);
			
			accounts.addItem( { label: "Default view option", data:1 } );
            accounts.addItem( { label: "Option 1", data:2 } );
            accounts.addItem( { label: "Option 2", data:3 } );
		    accounts.addItem( { label: "Option 3", data:4 } );
			
			accounts.x = 18;
			accounts.y = 18;
			accounts.width = 130;

			var range:Slider = new Slider();
			childContentBack.addChild(range);
			
			range.maximum = 10;
			range.minimum = 1;
			
			range.x = 18;
			range.y = 100;
			range.width = picWidth / 2;
			
			var contribs:CheckBox = new CheckBox();
			childContentBack.addChild(contribs);

			contribs.label = 'Add this display option?';
			
			contribs.x = 18;
			contribs.y = 50;
			contribs.width = 150;
			
			//CHANGE this code to change the icon that you click to flip the card
			var over:Over = new Over();
			childContentBack.addChild(over);
			over.x = 265;
			over.y = 175;
			over.addEventListener(MouseEvent.CLICK,sideClicked);
			
			return childContentBack;
		}
	}
}